Appendix 3 Typical Control Files for Pharmacokinetic Models

**NONMEM Control File of Final Recirculation Population Pharmacokinetic Model of Remimazolam (CNS7056001PBPK13S)**

$PROB CNS7056B SINGLE ASCENDING DOSE RECIRCULATION MODEL UNFIXED ARTERIAL VOLUME 5 ETAS

$INPUT ID AMT RATE CMT TIME DV MDV SEX WT AGE HR HR2 HR6 HR10

$DATA C:\NMVI\DATAFILES\CNS7056\CNS7056PBPKHR001.CSV

$SUBROUTINES ADVAN6 TOL=5

$MODEL

COMP=(CENTRAL,DEFOBS)

COMP=(LUNG)

COMP=(ARTERY,DEFDOSE)

COMP=(PERIPH)

COMP=(DEEP)

$PK

IF(AMT.GT.0) THEN

DOSE=AMT

ELSE

DOSE=DOSE

ENDIF

V2=WT/70 ;Volume of Lung

TVQ=THETA(1) ;Plasma Flow

TVCL=THETA(2) ;Systemic Clearance

TVV1=THETA(3) ;Central Volume

TVQ4=THETA(4) ;Inter-Tissue Clearance(4)

TVQ5=THETA(5) ;Inter-Tissue Clearance(5)

TVV4=THETA(6) ;Peripheral Volume

TVV5=THETA(7) ;Deep Volume

TVV3=THETA(8) ;Arterial Volume

Q=TVQ

CL=TVCL\*EXP(ETA(1))

V1=TVV1\*EXP(ETA(2))

V3=TVV3\*EXP(ETA(5))

V5=TVV5\*EXP(ETA(4))

V4=TVV4\*EXP(ETA(3))

Q4=TVQ4

Q5=TVQ5

AUC=DOSE/CL

S1=V1/1000

S3=V3/1000

VSS=V1+V2+V3+V4+V5

$DES

DADT(1)=(Q-Q4-Q5)\*A(3)/V3-(Q-Q4-Q5)\*A(1)/V1 ; Central

DADT(2)=(Q-Q4-Q5)\*A(1)/V1+Q4\*A(4)/V4+Q5\*A(5)/V5-Q\*A(2)/V2-CL\*A(4)/V4 ; Lung

DADT(3)=Q\*A(2)/V2-Q\*A(3)/V3 ; Artery

DADT(4)=Q4\*A(3)/V3-Q4\*A(4)/V4 ; Peripheral

DADT(5)=Q5\*A(3)/V3-Q5\*A(5)/V5 ; Deep

$ERROR

SIG1=0.017

SIG2=0.02

IPRED=F

Y=F\*EXP(EPS(1))+EPS(2)

IRES=DV-IPRED

IWRES=IRES/SQRT(F\*\*2\*SIG1+SIG2)

IF(DV.EQ.0) IWRES=0

$THETA

(100,219,500) ;Plasma Flow

(50,67.1,250) ;Systemic Clearance

(0.5,5.99) ;Central Volume

(20,145,200) ;Inter-Tissue Clearance(4)

(1,25.7,70) ;Inter-Tissue Clearance(5)

(0.5,8,30) ;Peripheral Volume

(5,21.7,100) ;Deep Volume

(0.2,1,5) ;Arterial Volume

$OMEGA

0.0355,1.32,1.5,0.0533,0.1

$SIGMA

0.1,5

$EST MAXEVAL=3000 SIGDIGITS=3 PRINT=20 NOABORT SORT METHOD=1 INTERACTION

$COV SLOW PRINT=E MATRIX=S

$TABLE ID AMT CMT CL ETA1 V1 ETA2 Q4 Q5 V2 V3 ETA5 V4 ETA3 V5 ETA4 Q

VSS AUC WT SEX TIME IPRED IWRES NOPRINT

FILE=C:\NMVI\OUTPUT\CNS7056\PBPK\CNS7056001PBPK13S.PAR

NONMEM Control File of Final 4-Compartment Population Pharmacokinetic Model of Midazolam (MIDAZOLAMCOMP51)

$PROB MIDAZOLAM 0.075 MG/KG 4 COMPARTMENTS PK

$INPUT ID AMT RATE CMT TIME DV MDV SEX AGE WT

$DATA C:\NMVI\DATAFILES\CNS7056\MIDAZOLAMCOMP.CSV

$SUBROUTINES ADVAN6 TOL=5

$MODEL

COMP=(CENTRAL,DEFOBS,DEFDOSE)

COMP=(PERIPH)

COMP=(DEEP)

COMP=(DEEPER)

$PK

IF(AMT.GT.0) THEN

DOSE=AMT

ELSE

DOSE=DOSE

ENDIF

TVCL=THETA(1) ;Systemic Clearance

TVQ4=THETA(2) ;Inter-Tissue Clearance(4)

TVV1=THETA(3) ;Central Volume

TVV4=THETA(4) ;Peripheral Volume

TVQ5=THETA(5) ;Inter-Tissue Clearance(5)

TVV5=THETA(6) ;Deep Volume

TVQ6=THETA(7) ;Inter-Tissue Clearance(6)

TVV6=THETA(8) ;Peripheral Volume(6)

CL=TVCL\*EXP(ETA(1))

V1=TVV1\*EXP(ETA(2))

V4=TVV4\*EXP(ETA(3))

V5=TVV5

Q4=TVQ4\*EXP(ETA(4))

Q5=TVQ5

V6=TVV6\*EXP(ETA(5))

Q6=TVQ6

S1=V1/1000

VSS=V1+V4+V5+V6

AUC=DOSE/CL

MRT=VSS/CL

AUMC=MRT\*AUC

$DES

DADT(1)=-Q4\*A(1)/V1-Q5\*A(1)/V1-Q6\*A(1)/V1+Q4\*A(2)/V4+Q5\*A(3)/V5+Q6\*A(4)/V6-CL\*A(1)/V1

DADT(2)=Q4\*A(1)/V1-Q4\*A(2)/V4

DADT(3)=Q5\*A(1)/V1-Q5\*A(3)/V5

DADT(4)=Q6\*A(1)/V1-Q6\*A(4)/V6

$ERROR

SIG1=0.026

SIG2=0.16

IPRED=F

Y=F\*EXP(EPS(1))+EPS(2)

IRES=DV-IPRED

IWRES=IRES/SQRT(F\*\*2\*SIG1+SIG2)

IF(DV.EQ.0) IWRES=0

$THETA

(10,20) ;Systemic Clearance

(10,100) ;Inter-Tissue Clearance(4)

(1,2) ;Central Volume

(1,20) ;Peripheral Volume

(1,50) ;Inter-Tissue Clearance(5)

(4,30) ;Deep Volume

(1,50) ;Inter-Tissue Clearance(6)

(4,10) ;Peripheral Volume(6)

$OMEGA

0.2,0.2,0.2,0.1,0.2

$SIGMA

0.5,20

$EST MAXEVAL=8000 SIGDIGITS=3 PRINT=20 NOABORT SORT METHOD=1 INTERACTION

$COV SLOW PRINT=E

$TABLE ID AMT CMT CL ETA1 V1 ETA2 V4 ETA3 Q4 ETA4 Q5 V5 Q6 V6 ETA5 VSS AUC MRT AUMC WT SEX TIME IPRED IWRES NOPRINT

FILE=C:\NMVI\OUTPUT\CNS7056\MIDAZPK\MIDAZOLAMCOMP51.PAR