/* ROC_Area_For_Wilcoxon_Rank_Sum_Test.sas */
/*  
  SAS program to illustrate the use of PROC LOGISTIC 
   to get estimates for summary measures the Wilcoxon rank 
   sum test:  p'' = Pr(X<Y) and its WMWodds transformation,
   along with their its 95% confidence limits
  Author: George Divine, PhD
          Department of Public Health Sciences
          Henry Ford Health System
  Creation/Revision Date: June 7, 2013
*/

/* Input example data from: 
     Hunt R, Dienemann J, Norton HJ, Hartley W, Hudgens A, Stern
     T, Divine G. Aromatherapy as treatment for postoperative nausea:
     a randomized trial. Anesth Analg 2012 Mar 5. [Epub ahead of print]
     PMID: 22392970
*/
data hunt3;
  input group change n;
  label
    change = 'Change in PON Score'
   ;
cards;
0 -3 0
0 -2 5
0 -1 24
0  0 40
0 +1 4
1 -3 0
1 -2 6 
1 -1 34
1  0 33
1 +1 5
2 -3 2
2 -2 11
2 -1 38
2  0 23
2 +1 2
3 -3 4
3 -2 11
3 -1 46
3  0 12
3 +1 1
;
run;
proc format;
  value grp 0='Saline' 1='Alcohol' 2='Ginger' 3='Blend';
run;
/* If the treatment group is used as the binary outcome, PROC LOGISTIC will estimate p'' */
proc logistic data=hunt3 ;
  class group;
  model group=change;
  freq n;
  format group grp.;
 /* Restrict the Comparison to Ginger vs Blend */
  where group=2 or group=3;
  title3 'For PROC LOGISTIC with the default options, "c",'; 
  title4 '(found at the bottom of the last page of output)';
  title5 'is an estimate of p'''' = Pr(X<Y)';
run;
/* The ROC option will produced a confidence interval for c which is equivalent to p'' */
proc logistic data=hunt3 ;
  class group;
  model group=change;
  freq n;
  roc;
 /* Output dataset with the estimate for the ROC area (= c = p'') and its confidence limits */
  ods output rocAssociation=roc_est;
  format group grp.;
  where group=2 or group=3;
  title3 "Using the ROC option estimates p'' (the ROC Area) and its 95% Confidence Limits";
run;
title3;
data roc_est2; set roc_est;
 /* Compute the WMWodds and its confidence limits */
 /* Also note that the WMWodds should not be confused with the logistic regression odds ratio! */
  WMWodds = Area/(1-Area);
  WMWodds_Lower_Delong = lowerArea/(1-lowerArea);
  WMWodds_Upper_Delong = UpperArea/(1-UpperArea);
  if _n_=1;
  label 
    Area="ROC Area/c-statistic/Pr(X<Y)"
   ;
run;
/* Print the statistics of interest */
proc print label;
  var area lowerArea UpperArea WMWodds WMWodds_Lower_Delong WMWodds_Upper_Delong ;
  Format area lowerArea UpperArea WMWodds WMWodds_Lower_Delong WMWodds_Upper_Delong 5.2;
  title3 'The ROC Area estimate and confidence limits, along with their transformations to WMWodds';
 /* Note: The limits in Table 3 of Hunt, et al, were computed after rounding to 2 decimal places */
run;
title3;