**Supplementary Digital Content 3. SQL Query Used to Ascertain Aspirin Exposure**

/\*BEGIN WITH EXCLUSION CRITERIA FOR ASPIRIN EXPOSURE (ALLERGY)

REPLACE 'ProjectName' WITH CORRECT PROJECT\*/

SELECT DISTINCT PatientSID, AllergySID, AllergicReactant, VerificationDateTime, VerifiedFlag, EnteredInErrorFlag

INTO ProjectName.Dflt.AspirinAllergy

FROM ProjectName.Src.Allergy\_Allergy T1

WHERE T1.CohortName = 'control'

AND T1.VerifiedFlag = 'Y'

AND (T1.AllergicReactant LIKE '%aspirin%' OR T1.AllergicReactant LIKE 'ASA' OR T1.AllergicReactant LIKE 'ASA %' OR T1.AllergicReactant LIKE '%asprin%' OR T1.AllergicReactant LIKE '%aspirn%')

GO

-- SOME REACTANTS ARE NOT RELEVANT AND MAY NEED TO BE REMOVED FROM THE ALLERGY TABLE

DELETE FROM ProjectName.Dflt.AspirinAllergy

WHERE AllergicReactant in ('? ASPIRIN', '?aspirin', 'ASA ?', 'no known allergies. no h/o allergy to aspirin.', 'not allergic to aspirin!!!!', 'please delete allergy to penicillin, aspirin. pt states is not allergic to anything.')

GO

-- REMOVE ENTRIES THAT WERE ENTERED IN ERROR

DELETE FROM ProjectName.Dflt.AspirinAllergy

WHERE EnteredInErrorFlag = 'Y'

GO

-- ONLY APPLY ASPIRIN ALLERGY TO THOSE WITH DOCUMENTATION PRIOR TO A SET BASELINE DATE

ALTER TABLE ProjectName.Dflt.AspirinAllergy

ADD ALLERGY INT

GO

UPDATE ProjectName.Dflt.AllergySample

SET ALLERGY = 1

WHERE PatientSID IN

(

SELECT T2.PatientSID

FROM ProjectName.Dflt.AspirinAllergy T1

INNER JOIN ProjectName.Dflt.Cohort T2

ON T1.PatientSID = T2.PatientSID

WHERE (DATEDIFF(DAY, T2.BaselineDate, CAST(T1.VerificationDateTime AS DATE)) <=0)

)

GO

/\* NEXT IS IDENTIFYING ALL CDW DOCUMENTATION OF ASPIRIN MEDICATION RECORDS FROM VA AND NON-VA SOURCES\*/

SELECT DISTINCT T1.DrugNameWithoutDose, T1.LocalDrugSID, T1.Sta3n

INTO ProjectName.Dflt.AspirinID

FROM CDWWork.Dim.LocalDrug T1

WHERE (T1.DrugNameWithoutDose LIKE '%aspirin%' OR T1.DrugNameWithoutDose LIKE 'ASA' OR T1.DrugNameWithoutDose LIKE 'ASA %' OR T1.DrugNameWithoutDose LIKE '%asprin%' OR T1.DrugNameWithoutDose LIKE '%aspirn%')

GO

-- CREATE TABLE THAT CONTAINS ASPIRIN MEDICATION RECORD INFORMATION FOR SUBJECTS WITHIN THE YEAR PRIOR TO BASELINE DATE

SELECT DISTINCT T2.PatientSID, '1' AS Aspirin, T1.LocalDrugNameWithDose

INTO ProjectName.Dflt.AspirinRxEx

FROM ProjectName.Src.RxOut\_RxOutpatFill T1

INNER JOIN ProjectName.Dflt.Cohort T2

ON T1.PatientSID = T2.PatientSID

INNER JOIN ProjectName.Dflt.AspirinID T3

ON T3.DrugNameWithoutDose = T1.DrugNameWithoutDose

WHERE (DATEDIFF(DAY, BaselineDate, T1.FillDateTime) <= 0

AND DATEDIFF(DAY, BaselineDate, T1.FillDateTime) >= -365)

GO

-- NON-VA MEDICATION EXPOSURE FOR THE YEAR PRIOR TO BASELINE DATE

SELECT DISTINCT T1.PatientSID, T2.DrugNameWithoutDose, T1.DocumentedDateTime,

T3.ProcedureDateTime, T1.Sta3n, DATEDIFF(DAY, T3.ProcedureDateTime, T1.DocumentedDateTime)

INTO ProjectName.Dflt.AspirinRxExNonVA

FROM ProjectName.Src.NonVAMed\_NonVAMed T1

INNER JOIN ProjectName.Dflt.AspirinIDExpanded T2

ON T1.LocalDrugSID = T2.LocalDrugSID AND T1.Sta3n = T2.Sta3n

INNER JOIN ProjectName.Dflt.IDKey T3

ON T1.PatientSID = T3.PatientSID

WHERE (DATEDIFF(DAY, T3.ProcedureDateTime, T1.DocumentedDateTime) <= 0

AND DATEDIFF(DAY, T3.ProcedureDateTime, T1.DocumentedDateTime) >= -365)

GO

-- MERGE VA AND NON-VA ASPIRIN DOSAGE

SELECT DISTINCT T1.PatientSID, T1.ASPIRIN, T1.LocalDrugNameWithDose AS DrugName

INTO ProjectName.Dflt.AspirinRxExAll

FROM ProjectName.Dflt.AspirinRxEx T1

UNION

SELECT DISTINCT T2.PatientSID, '1' AS Aspirin, T2.DrugNameWithoutDose AS DrugName

FROM ProjectName.Dflt.AspirinRxExNonVA T2

GO

-- CREATE SQL COHORT OF ASPIRIN EXPOSURE

DECLARE @ContainsText VARCHAR(8000);

SET @ContainsText = '(near(("ASA", "81"), 6) or near(("ASA", "162"), 6) or near(("ASA", "325"), 6) or near(("asa", "baby"), 3) or near(("asa", "yes"), 3) or near(("ASA", "81mg"), 6) or near(("ASA", "162mg"), 6) or near(("ASA", "325mg"), 6) or near(("aspirin", "resume"), 3) or near(("aspirin", "yes"), 3) or near(("aspirin", "baby"), 3) or near(("aspirin", "81"), 6) or near(("aspirin", "162"), 6) or near(("aspirin", "325"), 6) or near(("aspirin", "81mg"), 6) or near(("aspirin", "162mg"), 6) or near(("aspirin", "325mg"), 6)) and not near(("aspirin", "not"), 5) and not near(("aspirin", "avoid"), 3) and not near(("aspirin", "stop"), 5) and not near(("allergies", "aspirin"), 150) ';

SELECT DISTINCT T2.PatientSID, T2.ProcedureDateTime AS BaselineDate, CAST(T3.ReferenceDateTime AS DATE) AS ReferenceDate, T3.TIUDocumentSID

INTO ProjectName.Dflt.AspirinSqlCase

FROM ProjectName.Src.tvf\_TIU\_FullTextSearch(@ContainsText) T1

INNER JOIN ProjectName.Src.TIU\_TIUDocument\_8925 T3

ON T1.TIUDocumentSID = T3.TIUDocumentSID

INNER JOIN ProjectName.Dflt.Cohort T2

ON T2.PatientSID = T3.PatientSID

WHERE (DATEDIFF(DAY, ProcedureDateTime, CAST(ReferenceDateTime AS DATE)) <= 0

AND DATEDIFF(DAY, ProcedureDateTime, CAST(ReferenceDateTime AS DATE)) >= -365)

GO

--- CREATE EXPOSURE DEFINITION

ALTER TABLE ProjectName.Dflt.AspirinSqlCase

ADD ASPIRIN INT

GO

--- ASPIRIN DOSAGE ARE THOSE WITH MORE THAN ONE INSTANCE OF EXPOSURE

UPDATE T1

SET ASPIRIN = 1

FROM ProjectName.Dflt.AspirinSqlCase T1

INNER JOIN

(

SELECT DISTINCT T1.PatientSID

FROM

(

SELECT PatientSID, BaselineDate, ReferenceDate, TIUDocumentSID, ROWNUM = (ROW\_NUMBER() OVER (PARTITION BY PatientSID ORDER BY ReferenceDate DESC))

FROM ProjectName.Dflt.AspirinSqlCase

) T1

WHERE T1.ROWNUM > 1

) T2

ON T1.PatientSID = T2.PatientSID

GO